Newbie learning how to create Hot Mail accounts and save them

[erussx2 6]

So Far i have this code:  

 

 

 

reset account("Any")
set(#eMailProvider, "{$account data("Username")}{$rand(100, 999)}.com", "Global")
set(#signIn, "{$change text casing($account data("First Name"), "Lower Case")}{$rand(18725, 98971)}", "Global")
clear cookies
navigate("https://signup.live.com/signup.aspx", "Wait")
wait for browser event("Everything Loaded", "")
type text(<first name field>, $account data("First Name"), "Standard")
type text(<last name field>, $account data("Last Name"), "Standard")
change dropdown(<birth month dropdown>, "Random")
change dropdown(<birth day dropdown>, "Random")
change dropdown(<birth year dropdown>, "Random")
change dropdown(<sex dropdown>, "Male")
type text(<name="imembernamelive">, $account data("First Name"), "Standard")
type text($element offset(<email field>, 0), "{#signIn}@{#eMailProvider}", "Standard")
type text(<name="iPwd">, "{$account data("Password")}Aa", "Standard")
type text(<name="iRetypePwd">, "{$account data("Password")}Aa", "Standard")
set(#securityReply, "{$account data("Last Name")}{$rand(1965, 2013)}", "Global")
click(<id="iqsaswitch">, "Left Click", "No")
wait(1)
change dropdown(<name="iSQ">, "Random - Skip First Choice")
type text(<name="iSA">, #securityReply, "Standard")
change dropdown($element offset(<name="iCountry">, 1), " U.S.")
type text(<zip code field>, $account data("Zip Code"), "Standard")
change checkbox(<id="iOptinEmail">, "Unchecked")
wait($rand(1, 3))
click(<onclick="SignUp.DoPost();return false;">, "Left Click", "No")
wait for element(<id="iSummaryPageHeading">, "", "Appear")
save to file("{$special folder("Desktop")}\\hotmail Accounts.csv", "{$account data("First Name")},{$account data("Last Name")},{#signIn}@{#eMailProvider},{$account data("Username")},{$account data("Password")}Aa,{$account data("Zip Code")},#securityReply")

 

 

 

Disregard thumbnail image.  Im not getting that anymore.

[erussx2 6]

I have no idea why it says I have no license in my profile.  I purchased the developer license last thursday.

[erussx2 6]

What I want now is to get the bot to save each new account data to a new csv file n the folder that I tell it to. 

 

Special thanks to Anonym, because he has been helping me so far.

[Anonym 53]

Well, you need to change this line to start with:

 

 

set(#eMailProvider, "{$account data("Username")}{$rand(100, 999)}.com", "Global")

 

 

...because it appears to me that Hotmail nowadays wants to have another valid email account so that you can verify your Hotmail account. This row you have to change to something else, something that is valid.

 

Why not go with something like this instead:

 

 

ui drop down("Number of Hotmail accounts", "1,2,3,4,5,6,7,8,9,10,15,20,25,30,35,40,45,50", #numAccounts)
ui open file("Confirmation email addresses", #confirmationEmailsFile)
ui stat monitor("SessionID> ", #sessionID)
ui stat monitor("Status> ", #statusMsg)
ui stat monitor("Num of accounts created> ", #i)
set(#sessionID, $rand(1000, 9999), "Global")
loop while($folder exists("{$special folder("Application")}\\{#sessionID}")) {
    set(#sessionID, $rand(1000, 9999), "Global")
}
create folder($special folder("Application"), #sessionID)
set(#storePath, "{$special folder("Application")}\\{#sessionID}", "Global")
set(#accountsFile, "{#storePath}\\hotmail-accounts.csv", "Global")
clear list(%confirmationEmails)
add list to list(%confirmationEmails, $list from file(#confirmationEmailsFile), "Delete", "Global")
set(#tmp, $list total(%confirmationEmails), "Global")
if($comparison(#numAccounts, ">", #tmp)) {
    then {
        alert("Sorry dude! You can't create more accounts than the number of confirmation email accounts. Adjusting to {#tmp} accounts.")
        set(#numAccounts, #tmp, "Global")
    }
    else {
    }
}
set(#i, 0, "Global")
clear table(&accounts)
loop(#numAccounts) {
    reset account("Male")
    set(#confirmationEmail, $list item(%confirmationEmails, #i), "Global")
    clear cookies
    navigate("https://signup.live.com/signup.aspx", "Wait")
    wait for browser event("Everything Loaded", "")
    type text(<id="iFirstName">, $account data("First Name"), "Standard")
    type text(<id="iLastName">, $account data("Last Name"), "Standard")
    change dropdown(<id="iBirthMonth">, "Random - Skip First Choice")
    change dropdown(<id="iBirthDay">, "Random - Skip First Choice")
    change attribute(<id="iBirthYear">, "value", $rand(1965, 1988))
    change dropdown(<id="iGender">, "Male")
    type text(<name="imembernamelive">, $account data("First Name"), "Standard")
    type text($element offset(<email field>, 0), #confirmationEmail, "Standard")
    type text(<name="iPwd">, "{$account data("Password")}Aa", "Standard")
    type text(<name="iRetypePwd">, "{$account data("Password")}Aa", "Standard")
    set(#securityReply, "{$account data("Last Name")}{$rand(1965, 2013)}", "Global")
    click(<id="iqsaswitch">, "Left Click", "No")
    wait(1)
    change dropdown(<name="iSQ">, "Random - Skip First Choice")
    type text(<name="iSA">, #securityReply, "Standard")
    change dropdown($element offset(<name="iCountry">, 1), " U.S.")
    type text(<zip code field>, $account data("Zip Code"), "Standard")
    change checkbox(<id="iOptinEmail">, "Unchecked")
    type text(<id=w"wlspispSolutionElement*">, $solve captcha(<id=w"wlspispHIPBimg*">), "Standard")
    wait($rand(1, 3))
    click(<onclick="SignUp.DoPost();return false;">, "Left Click", "No")
    wait(2)
    loop while($exists(<id=w"wlspispHIPErrorWrong*">)) {
        change attribute(<id=w"wlspispSolutionElement*">, "value", $nothing)
        type text(<id=w"wlspispSolutionElement*">, $solve captcha(<id=w"wlspispHIPBimg*">), "Standard")
        click(<onclick="SignUp.DoPost();return false;">, "Left Click", "No")
        wait(2)
    }
    wait for element(<id="iSummaryPageHeading">, "", "Appear")
    set table cell(&accounts, #i, 0, $account data("First Name"))
    set table cell(&accounts, #i, 1, $account data("Last Name"))
    set table cell(&accounts, #i, 2, #confirmationEmail)
    set table cell(&accounts, #i, 3, $account data("Username"))
    set table cell(&accounts, #i, 4, $account data("Password"))
    set table cell(&accounts, #i, 5, $account data("Zip Code"))
    set table cell(&accounts, #i, 6, #securityReply)
    save to file(#accountsFile, &accounts)
    increment(#i)
}
alert("Finalised! The accounts are stored in the folder named {#sessionID}.")

 

I think I need to explain why I do the first loop in this script. It's just because I want to be able to save new account files without overwriting existing files. To handle that I create get a random number (#sessionID) that I use to create a folder inside your application folder with that name.

 

The reason why I save the accounts table in every loop is if you create a lot of accounts and the bot for some reason halts, then you will at least have some of the accounts stored. You could of course save every 10th time you create an account (but let's not do that right now so that we don't over complicate things).

 

It seem to be working, but there is an error that shows up when you enter the wrong CAPTCHA code and I don't have time to help right now, I'm sorry. Then again, you need to try this yourself to learn.

[Anonym 53]

Regarding the license: the license verification server seem to have been inaccessible during today. I got the same error.

[erussx2 6]

So I see that the code above works in the debugger but not in real life.  This is where i struggle, to bring the debugger to life.

[Anonym 53]

That's a typical sign of that you need to add a few extra wait commands in between nodes.

[AutomationNinja 194]

just wait till the accounts get frozen. hotmail is a pain..

[erussx2 6]

just wait till the accounts get frozen. hotmail is a pain..

 

 

You have a better email to create accounts with?

 

why would they freeze them?