[Free] Http Post Recaptcha Solving With 2Captcha

[heopas 90]

Hello, i am here again with a new script. This script use http post plugin and 2captcha to solve captcha without using browser.

This function return g-recaptcha-response that you use later. Sites use g-recaptcha-response with GET or POST.

If this method worked for you like my post

g-recaptcha-response example:

http://www.SOME-ESHOP-THAT-HAS-RECAPTCHA-FOR-ADD-TO-CART.com/en/cart/add?id=179956&g-recaptcha-response=03AHJ_VusKr5cuo3aNC8XQkwxb2MrKsFS0RsOTxj7tghv-VyWrMn18_vcMbfIa_EMIEc8svwKM-sN6VcRHrDph7F0dmAD6VjNs3guTtx8_SjdEzbdkQd_0Fw1-yPAkiFdsNrb71ppWaR2rNLX76CmjlldK-eFVHHjOHhpagCICYPpr_U2oZovekzbhUG3USEuwA-G7jbiAR0lOa49gR-UmD2RsUPsWJ3n8oENIMzvJ6g6rDXA4LdqBHghRD7Qan9gnbDOaJF188-MXrziGOz6QveVcFMlthaK_8i9vJ-xaaY-dzmotbHQ265_Y9OJ-56DguTDPLlPF5nM8ar6Orcvk1rrTZJQ2pORQ95tX13vE41nbs3wD5twa97YyzDUgqEvN0KIZ8RSMVYeE

set(#proxy,"","Global")
set(#useragent,$plugin function("HTTP post.dll", "$http useragent string", "Chrome 32.0 Win7 64-bit"),"Global")
alert($HttpReCaptchaSolve(0, "http://patrickhlauke.github.io/recaptcha/", $plugin function("HTTP post.dll", "$http get", "http://patrickhlauke.github.io/recaptcha/", #useragent, "", #proxy, "")))
define $HttpReCaptchaSolve(#localThreadID, #url, #post) {
    set(#recaptcha_image_location,"{$special folder("Application")}\\recaptchaImage{#localThreadID}.jpg","Local")
    set(#recaptcha_access_key,"YOUR 2CAPTCHA API KEY GOES HERE","Local")
    set(#sitekey,$plugin function("HTTP post.dll", "$xpath parser", #post, "//div[@class=\"g-recaptcha\"]", "data-sitekey", "HTML"),"Local")
    set(#post,$plugin function("HTTP post.dll", "$http get", "https://www.google.com/recaptcha/api.js", #useragent, #url, #proxy, ""),"Local")
    set(#ver,$find regular expression(#post,"(?<=recaptcha/api2/).*?(?=/recaptcha__en)"),"Local")
    set(#post,$plugin function("HTTP post.dll", "$http get", "https://www.google.com/recaptcha/api/fallback?t=0&ff=true&hl=en&v={#ver}&k={#sitekey}", #useragent, #url, #proxy, ""),"Local")
    loop while($contains(#post,"fbc-imageselect-payload")) {
        set(#cseed,$plugin function("HTTP post.dll", "$xpath parser index", #post, "//input[@name=\"c\"]", 0, "value"),"Local")
        set(#imageaddress,"https://www.google.com{$plugin function("HTTP post.dll", "$http text encoder", "html decode", $plugin function("HTTP post.dll", "$xpath parser", #post, "//img[@class=\"fbc-imageselect-payload\"]", "src", "HTML"))}","Local")
        set(#imagetext,$clean text($plugin function("HTTP post.dll", "$xpath parser", #post, "//*[@class=\"fbc-imageselect-message-text\"]", "InnerText", "HTML")),"Local")
        plugin command("HTTP post.dll", "http set headers", "Cache-Control", "no-store,no-cache")
        plugin command("HTTP post.dll", "http set headers", "Pragma", "no-no-cache")
        if($file exists(#recaptcha_image_location)) {
            then {
                plugin command("Advanced Shell.dll", "delete file permanently", "{$special folder("Application")}\\recaptchaImage{#localThreadID}.jpg")
            }
        }
        plugin command("HTTP post.dll", "http file download", #imageaddress, #recaptcha_image_location, #proxy)
        plugin command("HTTP post.dll", "http clear headers")
        set(#recaptcha_2captcha_response,$plugin function("Advanced Captcha.dll", "$2captcha.com", #recaptcha_access_key, #recaptcha_image_location, "", "Recognize ReCAPTCHA Type 3", #imagetext),"Local")
        if($contains(#recaptcha_2captcha_response,"ERROR")) {
            then {
                alert(#recaptcha_2captcha_response)
                return(0)
            }
        }
        clear list(%recaptcha_result)
        add list to list(%recaptcha_result,$list from text(#recaptcha_2captcha_response,$new line),"Delete","Local")
        set(#recaptcha_2captcha_id,$list item(%recaptcha_result,0),"Local")
        remove from list(%recaptcha_result,0)
        set(#postdata,"c={#cseed}","Local")
        set list position(%recaptcha_result,0)
        loop($list total(%recaptcha_result)) {
            set(#postdata,"{#postdata}&response={$subtract($next list item(%recaptcha_result),1)}","Local")
        }
        set(#post,$plugin function("HTTP post.dll", "$http post", "https://www.google.com/recaptcha/api/fallback?t=0&ff=true&hl=en&v={#ver}&k={#sitekey}", #postdata, #useragent, #url, #proxy, ""),"Local")
    }
    return($plugin function("HTTP post.dll", "$xpath parser", #post, "//*[@class=\"fbc-verification-token\"]", "InnerText", "HTML"))
}

[heopas 90]

Many people use it but no feedback, like etc.. Bad leechers

[mat123pl 2]

This solution has stopped working Do you have anything new?